IPP Mail Archive: IPP> RE: Revised ABNF per Monday's Phone C

IPP Mail Archive: IPP> RE: Revised ABNF per Monday's Phone C

IPP> RE: Revised ABNF per Monday's Phone Conference

From: Hastings, Tom N (hastings@cp10.es.xerox.com)
Date: Tue May 15 2001 - 14:00:45 EDT

  • Next message: Hastings, Tom N: "IPP> Telecon, Wed, May 16, 10-12 PDT (1-3 EDT): Media Types for Media Std"

    I believe that we agreed that the mm class names wouldn't need to be
    explicitly listed in the ABNF, since most new class names that are
    registered will be using the "mm" units. Then we don't have to update the
    ABNF, except in the unlikely event that a class name that uses "in" units is
    registered.

    Also we agreed that the registered class names couldn't have "-" in them,
    but could have "." (as in registry path names).

    So here is my suggested ABNF instead (which just changes the class2 line):

    media-size-self-describing-name =
              ( class1 "_" size-name "_" short-dim "x" long-dim "in" ) |
              ( class2 "_" size-name "_" short-dim "x" long-dim "mm" )

       class1 = "na" | "asme" | "oe"

       class2 = lowalpha *( lowalpha | digit | "." )

       size-name = ( lowalpha | digit ) *( lowalpha | digit | "-" )

       short-dim = dim

       long-dim = dim

       dim = integer-part [fraction-part] | "0" fraction-part

       integer-part = non-zero-digit *digit

       fraction-part = "." *digit non-zero-digit

       lowalpha = "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" |
                  "j" | "k" | "l" | "m" | "n" | "o" | "p" | "q" | "r" |
                  "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z"

       non-zero-digit = "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

       digit = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

    -----Original Message-----
    From: Bergman, Ron [mailto:Ron.Bergman@Hitachi-hkis.com]
    Sent: Tuesday, May 15, 2001 09:18
    To: Tom Hastings (E-mail); Ira McDonald (E-mail); Don Wright (E-mail)
    Cc: 'ipp@pwg.org'
    Subject: Revised ABNF per Monday's Phone Conference

    Here is my proposed ABNF to document the agreed restrictions in yesterday's
    phone call. I may be missing some of the class names but this should
    correctly linl\k each class to only one set of units.

    media-size-self-describing-name =
              ( class1 "_" size-name "_" short-dim "-" long-dim "in" ) |
              ( class2 "_" size-name "_" short-dim "-" long-dim "mm" )

       class1 = "na" | "asme" | "oe"

       class2 = "iso" | "jis" | "jpn" | "prc" | "roc" | "om"

       size-name = ( lowalpha | digit ) *( lowalpha | digit | "-" )

       short-dim = dim

       long-dim = dim

       dim = integer-part [fraction-part] | "0" fraction-part

       integer-part = non-zero-digit *digit

       fraction-part = "." *digit non-zero-digit

       lowalpha = "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" |
                  "j" | "k" | "l" | "m" | "n" | "o" | "p" | "q" | "r" |
                  "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z"

       non-zero-digit = "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

       digit = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

    Any comments?

            Ron



    This archive was generated by hypermail 2b29 : Tue May 15 2001 - 14:02:25 EDT