I believe that we agreed on Monday's telecon that "custom" was a valid class
by itself. The implication is that the units of "mm" or "in" could be used.
We don't need two custom class names, one for in and one for mm, correct?
In the drafts of the standard the ABNF for custom has been separately
specified in a separate question.
Assuming that we do continue to keep the ABNF for custom separate, then I
suggest that the ABNF for custom should be (first "-" changed to "_" and
"last "-" changed to "x"):
custom-media-size-self-describing-name =
"custom" "_" [size-name ] "_" short-dim "x" long-dim ( "mm" | "in )
where size-name, short-dim, and long-dim are defined as Ron proposed in
yesterday's email:
size-name = ( lowalpha | digit ) *( lowalpha | digit | "-" )
short-dim = dim
long-dim = dim
dim = integer-part [fraction-part] | "0" fraction-part
integer-part = non-zero-digit *digit
fraction-part = "." *digit non-zero-digit
lowalpha = "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" |
"j" | "k" | "l" | "m" | "n" | "o" | "p" | "q" | "r" |
"s" | "t" | "u" | "v" | "w" | "x" | "y" | "z"
non-zero-digit = "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
digit = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
Presumably the names for min and max would be as follows:
5.2.2 The size-name "max" shall be reserved to indicate an upper size
limit of either a device or application. Also, the size-name "min" shall be
reserved to indicate a lower size limit. Example: For a device that can
process forms as small as 2 x 3 inches to 18 x 36 inches:
custom_max_18x36in and custom_min_2x3in
Comments?
Tom
-----Original Message-----
From: Herriot, Robert
Sent: Tuesday, May 15, 2001 16:31
To: Bergman, Ron; Hastings, Tom N; Ira McDonald (E-mail); Don Wright
(E-mail)
Cc: 'ipp@pwg.org'
Subject: RE: IPP> Revised ABNF per Monday's Phone Conference
I'm concerned about the syntax having required redundancy of class1 with
inches and class2 with mm. Do we want to make it illegal to have a metric
size with "na". If so, we don't need "in".
Also, how does one describe a custom size, such as "7-13in". The grammar
doesn't allow "custom_7-13in". Instead it must be "na-custom_7-13in",
"oe-custom_7-13in" or "asme-custom_7-13in". This doesn't seem right.
Bob Herriot
> -----Original Message-----
> From: Bergman, Ron [mailto:Ron.Bergman@Hitachi-hkis.com]
> Sent: Tuesday, May 15, 2001 9:18 AM
> To: Tom Hastings (E-mail); Ira McDonald (E-mail); Don Wright (E-mail)
> Cc: 'ipp@pwg.org'
> Subject: IPP> Revised ABNF per Monday's Phone Conference
>
>
> Here is my proposed ABNF to document the agreed restrictions
> in yesterday's
> phone call. I may be missing some of the class names but this should
> correctly linl\k each class to only one set of units.
>
>
> media-size-self-describing-name =
> ( class1 "_" size-name "_" short-dim "-" long-dim "in" ) |
> ( class2 "_" size-name "_" short-dim "-" long-dim "mm" )
>
> class1 = "na" | "asme" | "oe"
>
> class2 = "iso" | "jis" | "jpn" | "prc" | "roc" | "om"
>
> size-name = ( lowalpha | digit ) *( lowalpha | digit | "-" )
>
> short-dim = dim
>
> long-dim = dim
>
> dim = integer-part [fraction-part] | "0" fraction-part
>
> integer-part = non-zero-digit *digit
>
> fraction-part = "." *digit non-zero-digit
>
> lowalpha = "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" |
> "j" | "k" | "l" | "m" | "n" | "o" | "p" | "q" | "r" |
> "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z"
>
> non-zero-digit = "1" | "2" | "3" | "4" | "5" | "6" | "7" |
> "8" | "9"
>
> digit = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" |
> "8" | "9"
>
>
> Any comments?
>
> Ron
>
>
This archive was generated by hypermail 2b29 : Wed May 16 2001 - 12:14:54 EDT